ASP Form to Mail script

[yoitsike]

Hi,

I'm having a little difficulty with a E-mail form in ASP. It sends to my E-mail just fine but the responses when filling out the form do not appear in the e-mail, the e-mail is just blank. Can somebody help me out with the coding please?

This coding is on the actual asp form page..

<FORM ACTION="formtomail.asp" METHOD="post">
<p align="center">
<span class="style12">Name : </span>
<input type="text" size="51" maxlength="256" name="Name" style="width: 264px"><p align="center">
<span class="style12">E-mail : </span>
<input type="text" size="48" maxlength="256" name="Email" style="width: 266px"><p align="center">
<INPUT TYPE=submit value="Submit">
</FORM>

This is the page the form sends all the information to..

<%
Const cdoBasic = 1 'Use basic (clear-text) authentication.
Const cdoSendUsingPort = 2
'cdosys related
Dim iMsg
Dim iConf
Dim Flds
'mail related
Dim strMsg
Dim strTo
Dim strCC
Dim strFrom
Dim strSubject
Dim strTextBody


'==================begin your configuration=============================
'you must have a username and pass word or you will not be able to send
'
Dim sendusername : sendusername = "cyn@mycheaptravel.com"
Dim userpassword : userpassword = ""
Dim smtpserver : smtpserver = "mail54.opentransfer.com"
'end your configuration

'===================begin set your info here============================
'set your TO, CC, From, Subject and body here
'
strTo = "cyn@mycheaptravel.com"
strCC = ""
strFrom = "cyn@mycheaptravel.com"
strSubject = "My Cheap Travel Quotes"
strTextBody = ""
'end set your info here


'Create message and configuration objects
set iMsg = CreateObject("CDO.Message")
set iConf = CreateObject("CDO.Configuration")
Set Flds = iConf.Fields
'Apply settings to the configuration object
With Flds
' Specify the authentication mechanism to basic (clear-text) authentication.
.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = cdoBasic
' The username for authenticating to an SMTP server
.Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = sendusername
' The password used to authenticate to an SMTP server
.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = userpassword
' Port
.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = cdoSendUsingPort
'Specify mail server
.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = smtpserver
'Specify the timeout in seconds
.Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 10
' The port on which the SMTP service specified by the smtpserver field is listening for connections (typically 25)
.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
'Use SSL for the connection (False or True)
'.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = False
.Update
End With

'Apply the settings to the message object and send it
With iMsg
Set.Configuration = iConf
.To = strTo
.From = strFrom
If strCC <> "" Then
.CC = strCC
End If
.Subject = strSubject
.TextBody = strTextBody
'Send message
.Send
End With
' cleanup mail objects
Set iMsg = Nothing
Set iConf = Nothing
Set Flds = Nothing
%>

Can somebody please let me know why it is not sending the information that is posted on the form to my e-mail is something not coded properly? Thanks in advance!

[DanInMa]

you are not defining where the body of your message is coming from.

try changing

strTextBody = ""

to

strTextBody = request("email")

also in your form you ask for a name to be entered. did you want this included in the email somewhere?

[Old Pedant]

As Dan said, *YOU* have to create the body of the mail as you want it.

You could, for example, do something like this:

strTextBody = "Name: " & Request("Name") & vbNewLine & "Email: " & Request("Email") & vbNewLine
'end set your info here

The body *is* part of "your info".