How to load a xml source file from the server using asp?

[wanye]

hi all, i would like to know how to load a xml source file using asp after u have submitted the form to the server...? for example, i will like to view the updated xml file by clicking on a button on the page after i submitted the form to the server using asp... how to do that?

the script is as follow..

<%

'-----------------------------------------------------------
'The "loadXMLFile" Function accepts two parameters.
'strXMLFile - The path and file name of the XML file.
'strXSLFilee - The path and file name of the XSL file.
'-----------------------------------------------------------
Function loadXMLFile(strXMLFile, strXSLFile)

'Declare local variables
Dim objXML
Dim objXSL


'Instantiate the XMLDOM Object that will hold the XML file.
set objXML = Server.CreateObject("Microsoft.XMLDOM")

'Turn off asyncronous file loading.
objXML.async = false

'Load the XML file.
objXML.load(strXMLFile)


'Instantiate the XMLDOM Object that will hold the XSL file.
set objXSL = Server.CreateObject("Microsoft.XMLDOM")

'Turn off asyncronous file loading.
objXSL.async = false

'Load the XSL file.
objXSL.load(strXSLFile)


'Use the "transformNode" method of the XMLDOM to apply the
'XSL stylesheet to the XML document. Then the output is
'written to the client.
Response.Write(objXML.transformNode(objXSL))
End Function


'-----------------------------------------------------------
'The "updateXML" Function accepts one parameter.
'strXMLFile - The path and file name of the XML file.
'-----------------------------------------------------------
Function updateXML(strXMLFile)

'Declare local variables.
Dim objDom
Dim objRoot
Dim objField
Dim x


'Instantiate the XMLDOM Object.
set objDOM = Server.CreateObject("Microsoft.XMLDOM")

'Turn off asyncronous file loading.
objDOM.async = false

'Load the XML file.
objDOM.load strXMLFile


'Set the objRoot variable equal to the root element of the
'XML file by calling the documentElement method of the
'objDOM (XMLDOM) object.
Set objRoot = objDom.documentElement


'Iterate through the Form Collection and write the
'submitted values to the XML file.
For x = 1 to Request.Form.Count

'Check see if "btn" is in the submitted value, if so,
'it is a button and should be ignored.
If instr(1,Request.Form.Key(x),"btn") = 0 Then

'Set objField variable equal to a field_value element by
'calling the selectSingleNode method of the objRoot
'(documentElement) object. The SelectSingleNode method
'accepts a string parameter for querying the XML document.
'In this case, the current value of the key property of
'the Form Collection is used to find the appropriate
'field_value element (more on this later).
Set objField = objRoot.selectSingleNode("field[@id='" & _
Request.Form.Key(x) & "']/field_value")

'Set the text property of the objField (field_value)
'element equal to the value of the current form field.
objField.Text = Request.Form(x)
End If
Next


'After the XML file has been edited, is must be saved.
objDom.save strXMLFile


'Release all of your object references.
Set objDom = Nothing
Set objRoot = Nothing
Set objField = Nothing


'Call the loadXMLFile method, passing in the newly edited
'XML file and the updatedcontact.xsl style sheet. This will
'allow the client to see the edited information. More on the
'updatedcontact.xsl file later.

loadXMLFile strXMLFile,server.MapPath("updatedcontact1.xsl")
End Function


'Test to see if the form has been submitted. If it has,
'update the XML file. If not, transform the XML file for
'editing.
If Request.Form("btnSubmit") = "" Then
loadXMLFile server.MapPath("Contact1.xml"), _
server.MapPath("contact1.xsl")
Else
updateXML server.MapPath("Contact1.xml")
End If
%>